Arduino IDE 2.X-修改数据位置

`修改数据存档至当前目录.bat`，放置在 Arduino IDE 2.X 的根目录运行，相关文件都会存到该目录下的 `Local` 下
迁移其他电脑,只需要打开过一次IDE然后再执行这个脚本，就可以把已经安装好的库、开发板都还原
```bash
@echo off
setlocal enabledelayedexpansion
TITLE 修改Arduino IDE 2.x 数据到当前目录\Local

@REM 获取当前脚本所在目录
set "scriptDir=%~dp0"
@REM 设置配置文件路径
set "configFile=C:\Users\%USERNAME%\.arduinoIDE\arduino-cli.yaml"
@REM 保存的新路径，全部保存到该目录下
set "newLibrariesPath=!scriptDir!Local"

@REM 临时文件
set "tempFile=%temp%\arduino-cli.yaml.temp"
@REM 备份文件
set "backupFile=C:\Users\%USERNAME%\.arduinoIDE\arduino-cli.yaml.bak"

@REM 询问用户是否修改配置
set /p choice=修改配置还是还原配置(修改/还原 y/N):

if /i "%choice%"=="y" ( 
    @REM 判断是否存在备份文件
    if not exist "%backupFile%" (
        @REM 复制配置文件到备份文件
        copy "%configFile%" "%backupFile%" > nul
    )
    @REM 复制配置文件到临时文件
    copy "%configFile%" "%tempFile%" > nul
    @REM 替换 libraries 路径
    (for /f "delims=" %%a in (%tempFile%) do (
        set "line=%%a"
        if not "!line!"=="" (
            set "line=!line:libraries: %USERPROFILE%\AppData\Local\Arduino15\libraries=libraries: %newLibrariesPath%\libraries!"
            set "line=!line:data: %USERPROFILE%\AppData\Local\Arduino15=data: %newLibrariesPath%\data!"
            set "line=!line:downloads: %USERPROFILE%\AppData\Local\Arduino15\staging=downloads: %newLibrariesPath%\downloads!"
            set "line=!line:user: %USERPROFILE%\Documents\Arduino=user: %newLibrariesPath%\user!"
            echo !line!
        )
    )) > "%configFile%"
    @REM 清理临时文件
    del "%tempFile%"
    echo 路径修改完成！
) else (
    @REM 判断是否存在备份文件
    if exist "%backupFile%" (
        @REM 还原备份文件
        copy "%backupFile%" "%configFile%" > nul
        echo 已还原备份文件！
    ) else (
        echo 没有找到备份文件，无法进行还原！
    )
)
PAUSE
```