FreeRTOS-多任务基础

```c++
void <函数名称>(void *<空指针名称>){}		//FreeRTOS 的任务函数
xTaskCreate(<函数名称>,"<任务描述>",<分配内存空间(bit)>,<传入参数>,<优先级>,<任务参数>);		//FreeRTOS 新建任务
vTaskDelay(<持续tick数>);		//FreeRTOS 中等待(ESP32中delay就是用vTaskDelay实现的， 1tick = 1ms)

// 数据传递，常规数据
(void *)&<数据名称>		//新建任务的传入参数可以使用这个转换成空指针
<原数据类型> <转换后存入的变量> = *(<原数据类型> *)<空指针名称>;		//在任务函数中把空指针转换回原数据格式

// 结构体，转换空指针和传入任务方式和常规一样，转换回结构体和读取对象有区别
<结构体名称> *<转换后存入的变量> = (<结构体名称> *)<空指针名称>;		//空指针转换回结构体
<对象格式> <存入的变量> = <转换后的结构体>-><结构体中对象名称>;   // 在指针中，调用结构体中的成员，不能使用“.”，而要使用“->”去进行访问
```

## 基本多任务(LED灯)
```c++
// 新建函数，传入值 空指针
void task1(void *pt){
  // 循环外面的可以理解为 setup() 中的指令
  pinMode(23, OUTPUT);
  // 无限循环内，可以理解为 loop() 中的指令
  while(1){
    digitalWrite(23,!digitalRead(23));
    vTaskDelay(3000);   //代替 delay()，1 Task = 1 ms
  }
}
void task2(void *pt){
  pinMode(21, OUTPUT);
  while(1){
    digitalWrite(21,!digitalRead(21));
    vTaskDelay(1000);
  }
}

void setup() {
  Serial.begin(115200);
  Serial.print(portTICK_PERIOD_MS);   //查看 tick 于时间对应关系
  // 创建任务
  // xTaskCreate(<函数名称>,"<任务描述>",<分配内存空间(bit)>,<传入参数>,<优先级>,<任务参数>)
  xTaskCreate(task1,"Blink23",1024,NULL,1,NULL);
  xTaskCreate(task2,"Blink21",1024,NULL,1,NULL);
}

void loop() {
}
```

## 任务传递单参数
```c++
// 定义两个LED引脚
byte LED1_PIN = 23;
byte LED2_PIN = 21;

// 新建函数，传入值 空指针
void task1(void *pt) {
  // 逆向操作，完整的转换空指针类型到byte类型
  // 定义个byte指针类型
  byte * pbLEDPIN;
  // 把传入的空指针转换为byte指针地址
  pbLEDPIN = (byte *)pt;
  // 定义个byte类型
  byte LEDPIN;
  // 从byte指针地址获取数据
  LEDPIN = *pbLEDPIN;
  pinMode(LEDPIN, OUTPUT);
  while (1) {
    digitalWrite(LEDPIN, !digitalRead(LEDPIN));
    vTaskDelay(1000);
  }
}

void task2(void *pt) {
  // 逆向操作，简化的空指针类型转换byte类型
  // 定义个byte类型,把空指针转byte指针再转换为实际内容
  byte LEDPIN = *(byte *)pt;
  pinMode(LEDPIN, OUTPUT);
  while (1) {
    digitalWrite(LEDPIN, !digitalRead(LEDPIN));
    vTaskDelay(3000);
  }
}

void setup() {
  Serial.begin(115200);
  // 数据转为空指针用于任务的数据传递
  // 定义个byte指针变量
  byte * pbLED1PIN;
  // 获取数据的地址并赋值
  pbLED1PIN = &LED1_PIN;
  // 定义个空指针变量
  void * pvLED1PIN;
  // 把刚赋值的数据地址变量转换为空指针类型
  pvLED1PIN = (void *)pbLED1PIN;

// 创建任务
  // xTaskCreate(<函数名称>,"<任务描述>",<分配内存空间>,<传入参数>,<优先级>,<任务参数>)
  if (xTaskCreate(task1, "Blink23", 1024, pvLED1PIN, 1, NULL))Serial.println("Task1 Created.");
  // 简化版的数据转空指针，用于任务数据传输
  // (void *)&LED2_PIN，&LED2_PIN 把地址转换出来，然后再转换为空类型指针
  if (xTaskCreate(task2, "Blink21", 1024, (void *)&LED2_PIN, 1, NULL))Serial.println("Task2 Created.");
}

void loop() {
}
```

## 任务传递多参数(结构体)
```c++
// 定义结构体 LEDFLASH
typedef struct {
  // 包含两个成员
  byte pin;
  int delayTime;
} LEDFLASH;

// 新建函数，传入值 空指针，两个任务复用这一个函数
void ledFlash(void *pt) {
  // 把空类型的指针变量转换为 LEDFLASH(定义的结构体) 变量
  LEDFLASH * ptLedFlash = (LEDFLASH *)pt;
  // 在指针中，调用结构体中的成员，不能使用“.”，而要使用“->”去进行访问
  byte pin = ptLedFlash->pin;   //获取引脚
  int delayTime = ptLedFlash->delayTime;    //获取时间

pinMode(pin,OUTPUT);
  while (1) {
    digitalWrite(pin, !digitalRead(pin));
    vTaskDelay(delayTime);
  }
}

void setup() {
  Serial.begin(115200);

// 结构体声明两个LED变量
  LEDFLASH led1, led2;
  // 并设置两个LED的引脚和时间
  led1.pin = 23;
  led1.delayTime = 1000;
  led2.pin = 21;
  led2.delayTime = 3000;

// 创建任务
  // xTaskCreate(<函数名称>,"<任务描述>",<分配内存空间>,<传入参数>,<优先级>,<任务参数>)
  // (void *)&led1，把结构体转换为空指针传入任务
  if (xTaskCreate(ledFlash, "Blink23", 1024, (void *)&led1, 1, NULL))Serial.println("Task1 Created.");
  if (xTaskCreate(ledFlash, "Blink21", 1024, (void *)&led2, 1, NULL))Serial.println("Task2 Created.");
}

void loop() {
}
```

**相关内容视频**
[多任务点灯](https://www.bilibili.com/video/BV1RB4y1Q7be)|[wokwi_多任务点灯](https://wokwi.com/projects/332576245745189459)
[给任务通过空指针类型传递单个参数](https://www.bilibili.com/video/BV1M94y1S7HF)|[wokwi_单个参数传递](https://wokwi.com/projects/332592742088573523)
[给任务通过结构体传递多个参数](https://www.bilibili.com/video/BV1bt4y1s72R)|[wokwi_多个参数传递](https://wokwi.com/projects/332592846800421460)